Coulomb阻塞

Coulomb阻塞

考虑一个很小的量子点(dot)加载source和drain之间，并通过一个背电极来条件量子点。因为量子点很小，总电容很小，所以多放一个电子进去就需要付出显著的静电充能。当外界给不了这部分能量补充，那么量子点的电子数就是锁定的，从而电流被阻塞。

假设量子点与source、drain、背电极的电容分别是$C_s,C_D,C_g$，那么体系的总电容为

$C_\Sigma = C_S + C_D + C_g.$

如果量子点上有$N$个额外的电子，那么它的静电荷为

$Q = -Ne + Q_0,$

其中$Q_0$是外部电压通过电容在量子点上诱导出的背景电荷。首先来看背电极的作用，其诱导的背景电荷为

$Q_0 = C_g V_{bg}.$

因此量子点的静电能为

$U(N)=\frac{Q^2}{2C_\Sigma} =\frac{(-Ne + C_gV_{bg})^2}{2C_\Sigma}.\label{eq:b1}$

定义

$n_g = \frac{C_gV_{bg}}{e}, \qquad E_C = \frac{e^2}{2C_\Sigma},$

则方程$\eqref{eq:b1}$变为

$\boxed{ U(N)=E_C(N-n_g)^2. }$

这就是Coulomb阻塞的核心公式，可以看到对于每一个整数$N$，系统都有一条能量抛物线$U(N)$。随着背电极改变，$n_g$连续变化，这些抛物线会左右平移；然后真实的电子数必须取整数，所以系统只能在这些整数电荷态当中选择一个能量最低的。

这里出现一个情况：因为$n_g$是连续可调的，但电子数$N$是离散的，这意味着量子点的电荷不是连续变化的，而是在某一段背电压调控范围内保持不变，只有达到临界值才会突然变化$1$，这就是电荷量子化，也是产生Coulomb阻塞的根本原因。

这里背电极的作用是通过$n_g=C_gV_{bg}/e$连续的改变不同整数电荷态$N$的相对能量，当某个$N$态能量最低的时候，电子数就会被锁死在这个整数上；当$N$和$N+1$两个电荷态能量正好相等的时候，量子点就处在电荷简并点，此时电子就很容易进出，导电性能增强。电荷简并满足

$U(N)=U(N+1).$

代入

$E_C(N-n_g)^2=E_C(N+1-n_g)^2$

得到

$n_g = N+\frac12.$

也就是说当诱导电荷$n_g$达到电子数半整数倍时，相邻两个电荷态是简并的，此时阻塞被解除。因此当连续改变背电压的时候，量子点的电子数不是连续变化，而是

$N,\;N,\;N,\;N+1,\;N+1,\;N+1,\;N+2,\cdots$

电导峰则会出现在这些跳变点上。

零偏压情形

现在先考虑最简单的情形：source和drain之间没有偏压，即$V_{sd}=0$，此时左右两侧电极的化学势相同，记为$\mu_F$。如果量子点处在某个固定的电荷态$N$，那么要让电子再进入或者跑出量子点，都需要消耗一定的能量。只要该能量非零，那么电子就不会轻易的流过量子点，从而电导很小。但是在背电压调节到某个简并点$n_g=N+1/2$的时候，两个相邻电荷态$N$和$N+1$能量相同，电子数可以在这两个态之间自由波动，从而就会出现电导峰。因此在很小的偏压下连续改变$V_{\rm bg}$，就会看到典型的Coulomb振荡。对于最简单的充电模型，相邻电导峰之间满足

$C_g \Delta V_{bg}=e\qquad \Longrightarrow \qquad \Delta V_{bg} = \frac{e}{C_g}.$

可以看到电极的电容$C_g$越大，电导峰间距越小；但通常背电极离样品较远，$C_g$往往会比较小，因此电导峰间距通常比较大。

在真实的量子点中，除了充电能，通常还存在离散的单粒子能级$\epsilon_i$。此时总能表示为

$E(N)=\sum_{i=1}^{N}\varepsilon_i + E_C(N-n_g)^2.$

于是第$N+1$个电子进入量子点所需要的化学势为

$\mu_{N+1}=E(N+1)-E(N)$

即得到

${ \mu_{N+1}(V_{bg}) = \varepsilon_{N+1} + 2E_C\left(N+\frac12-n_g\right). }$

因为

$n_g=\frac{C_gV_{bg}}{e},\nonumber$

所以化学势$\mu_{N+1}$对$V_{\rm bg}$是线性依赖的。也就是说背电极的本质作用就是把量子点的一整套加电子/减电子化学势整体向上或者向下移动。当$\mu_{N+1}$被移动到和电极费米能$\mu_F$对其的时候就会发生共振导电。所以从化学势的角度来说，改变背电压就是在扫描“哪个电荷跃迁正好落在费米面上”。

有限偏压

在零偏压时，source和drain的化学势相同，电子只能“精确共振”时通过量子点；在有限偏压时，左右电极的化学势被拉开，形成了一个有限宽度的能量窗口，只要量子点的某个跃迁能级落在该窗口之内就会有电流通过。令

$\mu_S = \mu_F + \frac{eV_{sd}}{2},\qquad \mu_D = \mu_F - \frac{eV_{sd}}{2}.$

此时source和drain之间的偏压窗口宽度为

$\mu_S-\mu_D = eV_{sd}.$

现在对于某个量子点跃迁$\mu_{N+1}(V_{bg})$，如果它满足

$\mu_D < \mu_{N+1}(V_{bg}) < \mu_S,$

那么电子就可以先从source进入量子点然后再流出到drain，于是出现了隧穿电流。因此对于零偏压

$\mu_{N+1}(V_{bg})=\mu_F$

只有当

$\mu_{N+1}(V_{bg})=\mu_F$

是才会发生共振隧穿，它对应一个精确的$V_{\rm bg}$，所以此时看到的Coulomb峰。而在有限偏压下则是满足

$\mu_F-\frac{eV_{sd}}{2} < \mu_{N+1}(V_{bg}) < \mu_F+\frac{eV_{sd}}{2}.$

也就是说此时不再要求一个精确的$V_{\rm bg}$，只要能量落在一个宽度为$eV_{sd}$的窗口中即可。因此一旦加上有限偏压，每一个零偏压下的尖锐共振点，都会“展开”成一个有限宽度的导电区域。

上面的条件可以写的更加直观一些，假设$V_{bg}^{(N)}$是第$N$个零偏压共振位置，满足$\mu_{N+1}(V_{bg}^{(N)})=\mu_F$。在其附近将$\mu_{N+1}$做线性展开

$\mu_{N+1}(V_{bg})-\mu_F \approx -\alpha_g e\,(V_{bg}-V_{bg}^{(N)}),\qquad \alpha_g=\frac{C_g}{C_\Sigma}$

因此有限偏压下的导电条件为

$\left| \mu_{N+1}(V_{bg})-\mu_F \right| < \frac{e|V_{sd}|}{2}\quad\Longrightarrow \quad \alpha_g e\,|V_{bg}-V_{bg}^{(N)}| < \frac{e|V_{sd}|}{2}.$

整理得到

$|V_{sd}| > 2\alpha_g\,|V_{bg}-V_{bg}^{(N)}|.$

这表明围绕每一个零偏压共振峰$V_{bg}^{(N)}$，都会向有限偏压方向展开一个$V$字型的导电区域。而在两个相邻共振峰之间的中间区域，则在小偏压下始终没有导电，于是形成了一个个封闭的阻塞区域。这些封闭区域在$(V_{sd},V_{bg})$平面上就是Coulomb diamonds。

ClearAll["Global`*"];

(*----------parameters----------*)
Ec = 1.0;                (*charging-energy scale:Ec=e^2/(2 C\
\[CapitalSigma]),in arbitrary units*)
alphaG = 0.22;           (*gate lever arm~Cg/C\[CapitalSigma]*)
nMin = -2;               (*minimum charge state shown*)
nMax = 6;                (*maximum charge state shown*)

gamma = 0.08;            (*width of zero-bias peaks/line broadening*)
eta = 0.03;              (*smoothness of finite-bias transport window*)

vgMin = (nMin - 1)/alphaG;
vgMax = (nMax + 1)/alphaG;

vsdMax = 2.8;            (*bias range shown*)

(*----------basic formulas----------*)

(*electrostatic energy of charge state N*)
U[n_, vg_] := Ec (n - alphaG vg)^2;

(*addition electrochemical potential for N->N+1*)
mu[n_, vg_] := 2 Ec (n + 1/2 - alphaG vg);

(*smooth step: ~0 for x<0, ~1 for x>0*)
softStep[x_] := 1/(1 + Exp[-x/eta]);

(*----------1) charging-energy parabolas----------*)

parabolaPlot = 
  Plot[Evaluate@Table[U[n, vg], {n, nMin, nMax}], {vg, vgMin, vgMax}, 
   PlotStyle -> Table[ColorData[97][i], {i, 1, nMax - nMin + 1}], 
   Frame -> True, Axes -> False, 
   FrameLabel -> (Style[#, 15] & /@ {"Vbg", "U(N,Vbg)"}), 
   PlotLabel -> Style["Charging-energy parabolas", 15, Bold], 
   ImageSize -> 500, PlotRange -> {{vgMin, vgMax}, {-5, 20}}];

(*mark the degeneracy points n_g=N+1/2*)
degeneracyPoints = 
  Table[{(n + 1/2)/alphaG, U[n, (n + 1/2)/alphaG]}, {n, nMin, 
    nMax - 1}];

parabolaPlot = 
 Show[parabolaPlot, 
  Graphics[{Red, PointSize[0.018], Point[degeneracyPoints], Black}]]

(*----------2) zero-bias Coulomb oscillation----------*)

(*At zero bias,conductance peaks when mu[n,vg]=0*)
Gzero[vg_?NumericQ] := 
  Total@Table[Exp[-(mu[n, vg]/gamma)^2], {n, nMin, nMax - 1}];

peakPlot = 
 Plot[Gzero[vg], {vg, vgMin, vgMax}, PlotRange -> All, 
  PlotStyle -> {Thick, Blue}, Frame -> True, Axes -> False, 
  FrameLabel -> (Style[#, 15] & /@ {"Vbg", "G(Vsd=0)"}), 
  PlotLabel -> Style["Zero-bias Coulomb oscillation", 15, Bold], 
  ImageSize -> 500, GridLines -> Automatic]

(*----------3) finite-bias Coulomb diamonds----------*)

(*A sequential-tunneling channel opens when an addition energy enters \
the bias window:
|mu[n,vg]| < |Vsd|/2 We use a smooth approximation so that \
DensityPlot looks nice.*)

openChannel[vg_?NumericQ, vsd_?NumericQ] := 
  1 - Times @@ 
    Table[1 - softStep[Abs[vsd]/2 - Abs[mu[n, vg]]], {n, nMin, 
      nMax - 1}];

(*brighten the diamond edges a bit*)
edgeSignal[vg_?NumericQ, vsd_?NumericQ] := 
  Total@Table[
    Exp[-((mu[n, vg] - vsd/2)/gamma)^2] + 
     Exp[-((mu[n, vg] + vsd/2)/gamma)^2], {n, nMin, nMax - 1}];

Gmap[vg_?NumericQ, vsd_?NumericQ] := 
  0.65 openChannel[vg, vsd] + 0.35 edgeSignal[vg, vsd];

diamondPlot = 
 DensityPlot[
  Gmap[vg, vsd], {vg, vgMin, vgMax}, {vsd, -vsdMax, vsdMax}, 
  PlotPoints -> 90, MaxRecursion -> 2, PlotRange -> All, 
  Frame -> True, Axes -> False, 
  FrameLabel -> (Style[#, 15] & /@ {"Vbg", "Vsd"}), 
  PlotLabel -> Style["Coulomb diamonds", 15, Bold], ImageSize -> 520, 
  ColorFunction -> "SunsetColors", ColorFunctionScaling -> True]